User Tools

Site Tools


courses:intro.prototyping.fall.2016.oct20

More processing

Today we looked into displaying and manipulating images, and mouse and keyboard input. I was happy to see that the important basics seemed to work for everybody.

Images

Add the images to the project in the menu Sketch→Add file.. or drag and drop onto the code environment.

The minimum to show an image:

PImage myPictureVar; //Creating a variable to contain the image
 
void setup()
{
  myPictureVar = loadImage("myFile.jpg"); //storing the image in the variable
}
 
void draw()
{
  image(myPictureVar,0,0); //drawing the image from our variable at coordinate 0 and 0
}

The command “image()” that we use to place a picture can also be used to resize the picture if you give it height and width.

We also used the command “tint()” to change brightness, color and transparency of the image, and “filter” to add filters such as GRAY, THRESHOLD, INVERT, BLUR etc.

Text

Drawing text on the screen works in a very similar way with the basic command text(). If you want to use any other font than Processings' own, you need to “create” that font. To create a font you go to Tools→ Create font.. in Processing. Choose one you want to use, decide on a size, and copy the filename that will be generated. You need that in your code. Here's a basic example of text, using a font I created:

String someText;
PFont thatAwesomeFont;
 
void setup()
{
  size(640,480);
  fill(0);
  someText = "Bring me to your leader!";
  thatAwesomeFont = loadFont("Incubus-30.vlw");
  textFont(thatAwesomeFont);
}
 
void draw()
{
  text(someText,50,240);
}
Webcam

Here's the example code for getting a feed from your webcam. Each frame from that feed can then be manipulated as if it was a image like any other. Note the handy print-out letting you know what modes your camera has and is available to you.

import processing.video.*;
 
Capture cam;
 
void setup() {
  size(640, 480);
 
  String[] cameras = Capture.list();
 
  if (cameras.length == 0) {
    println("There are no cameras available for capture.");
    exit();
  } else {
    println("Available cameras:");
    for (int i = 0; i < cameras.length; i++) {
      print(cameras[i]);
      println(": "+i);
    }
 
    // The camera can be initialized directly using an 
    // element from the array returned by list():
    cam = new Capture(this, cameras[1]);
    cam.start();     
  }      
 
}
 
void draw() {
  if (cam.available() == true) {
    cam.read();
  }
  image(cam, 0, 0); //drawing the image contained in the variable "cam";
}
Video

We didn't have time to get into video, but it works like a combination of how we've used images and the webcam-example.

We need to add a library for video, then add the video file to the project. The library info can be found on the processing webpage under libraries->video. Under video you find the commands available to use with the variable containing your video. You can play, pause, jump, reverse and more! In draw we then load a frame at the time and display that frame using the image-command.

import processing.video.*;
Movie myMovie;
void setup() {
  size(640,480);   
  myMovie = new Movie(this, "video1.mp4");
  myMovie.loop();
  delay(100); //seems necessary for loop to start
}
 
void draw() {
  if(myMovie.available())
  {
    myMovie.read();
    image(myMovie, 0,0, 640, 480);
  }
}
Input

We looked at using the keyboard for input. For example when a key is pressed it will trigger a function called “keyPressed” if you've written it. You write this part completely outside of setup and draw. Within there you can get the value of the key pressed and either use that or just trigger something else.

The minimum:

void keyPressed()
{
  //here something would happen if any key is pressed
  if (key == 'd')
  {
    //here something would happen if the key pressed is 'd' 
  }
}

OR check keypressed, while inside draw()

if (keyPressed == true) 
{
    //code for stuff to happen
}

But for buttons that are not characters? Those keys are CODED, and you have to check for that first. This is how you use the arrow key UP:

void keyPressed()
{
  if (key == CODED)
  {
    if (keyCode == UP)
    {
      //here something happens if UP is pressed.
    }
  }
}    

What other CODED keys are there? Look in the reference for “keyCode”.

We also listed a bunch of other input-functions that work very similar:

keyReleased()
keyTyped()
 
mouseClicked()
mouseDragged()
mouseMoved()
mousePressed()
mouseReleased()
mouseWheel()

The small difference is of course found in the reference.

For the next time I want you to make something using images, and keyboard or mouse interaction. Even better if you can bring in some from the last time (color, brightness, position, amount, 2D-shapes on top).

If you feel comfortable with the previous stuff, I challenge you to look in on the webcam example and make something interactive that manipulates a webcam-feed.

courses/intro.prototyping.fall.2016.oct20.txt · Last modified: 2016/09/20 05:01 by rickard